mirror of
https://github.com/torvalds/linux.git
synced 2025-04-12 16:47:42 +00:00
a3ed4157b7
Use ftrace_regs instead of fgraph_ret_regs for tracing return value on function_graph tracer because of simplifying the callback interface. The CONFIG_HAVE_FUNCTION_GRAPH_RETVAL is also replaced by CONFIG_HAVE_FUNCTION_GRAPH_FREGS. Signed-off-by: Masami Hiramatsu (Google) <mhiramat@kernel.org> Acked-by: Heiko Carstens <hca@linux.ibm.com> Acked-by: Will Deacon <will@kernel.org> Cc: Catalin Marinas <catalin.marinas@arm.com> Cc: Alexei Starovoitov <alexei.starovoitov@gmail.com> Cc: Florent Revest <revest@chromium.org> Cc: Martin KaFai Lau <martin.lau@linux.dev> Cc: bpf <bpf@vger.kernel.org> Cc: Alexei Starovoitov <ast@kernel.org> Cc: Jiri Olsa <jolsa@kernel.org> Cc: Alan Maguire <alan.maguire@oracle.com> Cc: Mark Rutland <mark.rutland@arm.com> Cc: Huacai Chen <chenhuacai@kernel.org> Cc: WANG Xuerui <kernel@xen0n.name> Cc: Paul Walmsley <paul.walmsley@sifive.com> Cc: Palmer Dabbelt <palmer@dabbelt.com> Cc: Albert Ou <aou@eecs.berkeley.edu> Cc: Vasily Gorbik <gor@linux.ibm.com> Cc: Alexander Gordeev <agordeev@linux.ibm.com> Cc: Heiko Carstens <hca@linux.ibm.com> Cc: Christian Borntraeger <borntraeger@linux.ibm.com> Cc: Sven Schnelle <svens@linux.ibm.com> Cc: Thomas Gleixner <tglx@linutronix.de> Cc: Ingo Molnar <mingo@redhat.com> Cc: Borislav Petkov <bp@alien8.de> Cc: Dave Hansen <dave.hansen@linux.intel.com> Cc: x86@kernel.org Cc: "H. Peter Anvin" <hpa@zytor.com> Cc: Mathieu Desnoyers <mathieu.desnoyers@efficios.com> Link: https://lore.kernel.org/173518991508.391279.16635322774382197642.stgit@devnote2 Signed-off-by: Steven Rostedt (Google) <rostedt@goodmis.org>
102 lines
2.3 KiB
ArmAsm
102 lines
2.3 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* LoongArch specific _mcount support
|
|
*
|
|
* Copyright (C) 2022 Loongson Technology Corporation Limited
|
|
*/
|
|
|
|
#include <linux/export.h>
|
|
#include <asm/ftrace.h>
|
|
#include <asm/regdef.h>
|
|
#include <asm/stackframe.h>
|
|
|
|
.text
|
|
|
|
#define MCOUNT_S0_OFFSET (0)
|
|
#define MCOUNT_RA_OFFSET (SZREG)
|
|
#define MCOUNT_STACK_SIZE (2 * SZREG)
|
|
|
|
.macro MCOUNT_SAVE_REGS
|
|
PTR_ADDI sp, sp, -MCOUNT_STACK_SIZE
|
|
PTR_S s0, sp, MCOUNT_S0_OFFSET
|
|
PTR_S ra, sp, MCOUNT_RA_OFFSET
|
|
move s0, a0
|
|
.endm
|
|
|
|
.macro MCOUNT_RESTORE_REGS
|
|
move a0, s0
|
|
PTR_L ra, sp, MCOUNT_RA_OFFSET
|
|
PTR_L s0, sp, MCOUNT_S0_OFFSET
|
|
PTR_ADDI sp, sp, MCOUNT_STACK_SIZE
|
|
.endm
|
|
|
|
SYM_FUNC_START(_mcount)
|
|
la.pcrel t1, ftrace_stub
|
|
la.pcrel t2, ftrace_trace_function /* Prepare t2 for (1) */
|
|
PTR_L t2, t2, 0
|
|
beq t1, t2, fgraph_trace
|
|
|
|
MCOUNT_SAVE_REGS
|
|
|
|
move a0, ra /* arg0: self return address */
|
|
move a1, s0 /* arg1: parent's return address */
|
|
jirl ra, t2, 0 /* (1) call *ftrace_trace_function */
|
|
|
|
MCOUNT_RESTORE_REGS
|
|
|
|
fgraph_trace:
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
la.pcrel t1, ftrace_stub
|
|
la.pcrel t3, ftrace_graph_return
|
|
PTR_L t3, t3, 0
|
|
bne t1, t3, ftrace_graph_caller
|
|
la.pcrel t1, ftrace_graph_entry_stub
|
|
la.pcrel t3, ftrace_graph_entry
|
|
PTR_L t3, t3, 0
|
|
bne t1, t3, ftrace_graph_caller
|
|
#endif
|
|
|
|
SYM_INNER_LABEL(ftrace_stub, SYM_L_GLOBAL)
|
|
jr ra
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
SYM_INNER_LABEL(ftrace_graph_func, SYM_L_GLOBAL)
|
|
bl ftrace_stub
|
|
#endif
|
|
SYM_FUNC_END(_mcount)
|
|
EXPORT_SYMBOL(_mcount)
|
|
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
SYM_FUNC_START(ftrace_graph_caller)
|
|
MCOUNT_SAVE_REGS
|
|
|
|
PTR_ADDI a0, ra, -4 /* arg0: Callsite self return addr */
|
|
PTR_ADDI a1, sp, MCOUNT_STACK_SIZE /* arg1: Callsite sp */
|
|
move a2, s0 /* arg2: Callsite parent ra */
|
|
bl prepare_ftrace_return
|
|
|
|
MCOUNT_RESTORE_REGS
|
|
jr ra
|
|
SYM_FUNC_END(ftrace_graph_caller)
|
|
|
|
SYM_FUNC_START(return_to_handler)
|
|
/* Save return value regs */
|
|
PTR_ADDI sp, sp, -PT_SIZE
|
|
PTR_S a0, sp, PT_R4
|
|
PTR_S a1, sp, PT_R5
|
|
PTR_S zero, sp, PT_R22
|
|
|
|
move a0, sp
|
|
bl ftrace_return_to_handler
|
|
|
|
/* Restore the real parent address: a0 -> ra */
|
|
move ra, a0
|
|
|
|
/* Restore return value regs */
|
|
PTR_L a0, sp, PT_R4
|
|
PTR_L a1, sp, PT_R5
|
|
PTR_ADDI sp, sp, PT_SIZE
|
|
|
|
jr ra
|
|
SYM_FUNC_END(return_to_handler)
|
|
#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
|